cbf114c29d
- Top level 'make clean' and 'make distclean' now do not stop in case of errors - 'make distclean' now removes the object_script.* generated files - Added the Logo to the About dialog and also the application icon
44 lines
1.1 KiB
Prolog
44 lines
1.1 KiB
Prolog
TEMPLATE = app
|
|
CONFIG += qt
|
|
QT += network script
|
|
DEFINES += HAVE_REMOTE WPCAP
|
|
INCLUDEPATH += "../rpc"
|
|
win32 {
|
|
LIBS += -lwpcap -lpacket
|
|
CONFIG(debug, debug|release) {
|
|
LIBS += -L"../common/debug" -lostproto
|
|
LIBS += -L"../rpc/debug" -lpbrpc
|
|
POST_TARGETDEPS += \
|
|
"../common/debug/libostproto.a" \
|
|
"../rpc/debug/libpbrpc.a"
|
|
} else {
|
|
LIBS += -L"../common/release" -lostproto
|
|
LIBS += -L"../rpc/release" -lpbrpc
|
|
POST_TARGETDEPS += \
|
|
"../common/release/libostproto.a" \
|
|
"../rpc/release/libpbrpc.a"
|
|
}
|
|
} else {
|
|
LIBS += -lpcap
|
|
LIBS += -L"../common" -lostproto
|
|
LIBS += -L"../rpc" -lpbrpc
|
|
POST_TARGETDEPS += "../common/libostproto.a" "../rpc/libpbrpc.a"
|
|
}
|
|
LIBS += -lprotobuf
|
|
RESOURCES += drone.qrc
|
|
HEADERS += drone.h
|
|
FORMS += drone.ui
|
|
SOURCES += \
|
|
drone_main.cpp \
|
|
drone.cpp \
|
|
portmanager.cpp \
|
|
abstractport.cpp \
|
|
pcapport.cpp \
|
|
winpcapport.cpp
|
|
SOURCES += myservice.cpp
|
|
SOURCES += pcapextra.cpp
|
|
|
|
QMAKE_DISTCLEAN += object_script.*
|
|
|
|
include (../version.pri)
|